Витягніть ім'я файлу із шляху в Excel

Цей підручник пояснює, як застосовувати формули для вилучення імені файлу з розширенням або без нього із шляху до файлу в певній комірці в Excel.

Витягніть ім'я файлу з розширенням із шляху
Витягніть ім'я файлу без розширення із шляху

Витягніть ім'я файлу з розширенням із шляху

Як показано на скріншоті нижче, є список, що містить різні шляхи до файлів, і ви хочете витягти з них лише імена файлів із розширеннями, наступна формула допоможе вам вирішити проблему.

Загальна формула

=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))

Аргументи

Як користуватися цією формулою?

1. Виберіть порожню комірку для виведення назви файлу. У цьому випадку я вибираю комірку D3.

2. Введіть формулу нижче і натисніть на Що натомість? Створіть віртуальну версію себе у ключ. Виділіть комірку результату, а потім перетягніть її ручку заповнення до кінця, щоб застосувати її до інших комірок.

=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))

Тепер усі імена файлів із розширеннями у певних шляхах до файлів витягуються, як показано на наведеному вище знімку екрана.

примітки:

• У цій формулі B3 - це комірка, що містить шлях до файлу. Будь ласка, змініть його, як вам потрібно.
• Якщо ім'я файлу не перевищує 99 символів, нижченаведена коротша формула також може бути використана для вирішення проблеми. Дивіться наведений нижче знімок екрана.
  =TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
  

Як працює ця формула?

=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))

1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))

• LEN(B3): Функція LEN обчислює загальну довжину в "D: \\ files \ work \ Q1 \ Jan \ text.txt" і повертає результат як 30;
• LEN(SUBSTITUTE(B3,"\","")): Функція ЗАМІНИ замінює символ "\" нічим. Результат - "D: filesworkQ1Jantext.txt". А потім функція LEN обчислює загальну довжину "D: filesworkQ1Jantext.txt" і отримує результат 24;
• SUBSTITUTE(B3,"\","*",30-24): Функція ЗАМІНИ замінює третій символ (30-24 = 6) "\" у "D: \\ files \ work \ Q1 \ Jan \ text.txt" одним символом "*". Тут результат "D: \\ files \ work \ Q1 \ Jan * text.txt";
• FIND("*","D:\\files\work\Q1\Jan*text.txt"): Функція FIND знаходить позицію символу "*" у "D: \\ files \ work \ Q1 \ Jan * text.txt" і, нарешті, повертає 22. Тут означає, що символ "*" знаходиться на 22-й позиції в " D: \\ files \ work \ Q1 \ Jan * text.txt ".

2. =MID(B3,22+1,LEN(B3))

• Як показано вище, LEN (B3) повертає результат як 30, тут функція MID може відображатися як = MID ("D: \\ files \ work \ Q1 \ Jan \ text.txt", 23,30). Це означає, що функція MID витягує 30 символів із рядка "D: \\ files \ work \ Q1 \ Jan \ text.txt", починаючи з 23-го символу. Тут результат text.txt.

Витягніть ім'я файлу без розширення із шляху

Інша обставина - вам може знадобитися просто витягти ім'я файлу без розширення із шляху, як показано на скріншоті нижче. У цьому розділі буде наведена довга формула, яка допоможе вам це зробити.

Загальна формула

=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")

Аргументи

Як користуватися цією формулою?

1. Виберіть порожню комірку, щоб вивести ім’я файлу без розширення.

2. Введіть формулу нижче і натисніть на Що натомість? Створіть віртуальну версію себе у ключ. Виділіть комірку результату, а потім перетягніть її ручку заповнення до кінця, щоб застосувати її до інших комірок.

=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")

примітки: У цій формулі B3 - це комірка, що містить шлях до файлу. Будь ласка, змініть його, як вам потрібно.

Супутні функції

Пов’язані формули