перевершувати CHOOSE функція

Опис

Синтаксис та аргументи

Використання та приклади

• Приклад 1 - Основне використання: використання CHOOSE функція сама для вибору значення з аргументу списку
• Приклад 2 - повернення різних результатів на основі кількох умов
• Ex3 - повертає різні обчислені результати на основі умов
• Ex4 - Виберіть випадковий зі списку
• Приклад 5 - Об'єднати CHOOSE та VLOOKUP функції для повернення значення в лівому стовпці
• Приклад 6 - Повернути день тижня або місяць на основі заданої дати
• Приклад 7 - Повернення до дати наступного робочого дня / вихідних за даними сьогодні

---

Опис

Команда CHOOSE функція повертає значення зі списку аргументів значення на основі заданого номера індексу. Наприклад, CHOOSE(3,”Apple”,”Peach”,”Orange”) повертає помаранчевий, номер індексу - 3, а помаранчевий - третє значення після номера індексу у функції.

синтаксис та аргументи

Синтаксис формули

CHOOSE(index_num, value1, [value2], …)

Аргументи

Index_num: Вимагається. Числове значення від 1-254 до непрямого, яке значення аргументу буде вибрано. якщо номер_індексу виходить за межі шкали між 1-254, CHOOSE повертає #VALUE! значення помилки. Якщо index_num є десятковим значенням, його буде округлено до цілого числа перед використанням формули. Value1: Вимагається. Перше значення у формулі, яке можна вибрати. Value2: Необов’язково. Друге і до 254-го значення, з якого можна вибрати.

Value1, value2... можуть бути числами, текстами, формулами, посиланнями на клітинки або визначеною назвою.

значення, що повертається

Команда CHOOSE функція повертає значення зі списку на основі заданої позиції.

Використання та приклади

У цій частині я перелічую кілька простих, але репрезентативних прикладів, що пояснюють використання CHOOSE функції.

Приклад 1 - Основне використання: використання CHOOSE функція сама для вибору значення з аргументу списку

Формула1:

=CHOOSE(3,"a","b","c","d")

Повернення: c, що є третім аргументом після номера_індексу з 3 у CHOOSE функції.

Примітка: використання подвійних лапок навколо значення, якщо воно є текстом.

Формула2:

=CHOOSE(2,A1,A2,A3,A4)

Повернення: Кейт, значення А2. Оскільки index_num дорівнює 2, а A2 є другим значенням у CHOOSE функції.

Формула3:

=CHOOSE(4,8,9,7,6)

Повернення: 6, аргумент 4-го списку у функції.

---

Приклад 2 - повернення різних результатів на основі кількох умов

Припустимо, у вас є перелік відхилень для кожного товару, який потрібно було позначити відповідно до умов, як показано нижче.

Зазвичай ви можете використовувати функцію IF для обробки, але тут я представляю, як використовувати CHOOSE функція для легкого вирішення цієї проблеми

формула:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

Поясніть:

(B7>0)+(B7>1)+(B7>5): index_num, B7 дорівнює 2, що більше 0 та 1, але менше 5, тож ми отримуємо проміжний результат:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Як ми знаємо, True = 1, False = 0, тому формулу можна розглядати як:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

потім

=CHOOSE(2,"Top","Middle","Bottom")

Результат: Середній

---

Ex3 - повертає різні обчислені результати на основі умов

Припустимо, вам потрібно розрахувати знижки за кожен товар на основі суми та ціни, як показано на знімку екрана нижче:

формула:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

Поясніть:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 дорівнює 102, що більше 100, але менше 201, тому в цій частині він повертає результат, показаний як:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

потім

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: значення, з яких вибрати, знижка дорівнює ціні * сума * відсоток знижки, оскільки тут index_num дорівнює 2, він вибирає B8 * C8 * 0.2

Повертає: 102 * 2 * 0.2 = 40.8

---

Ex4 - Виберіть випадковий зі списку

У програмі Excel іноді може знадобитися випадковий вибір значення із заданого списку - CHOOSE функція може вирішити цю роботу.

Випадково виберіть одне значення зі списку:

формула:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

Поясніть:

RANDBETWEEN(1,5): index_num, випадковим чином отримуємо число від 1 до 5

$D$2,$D$3,$D$4,$D$5,$D$6: список значень, з яких можна вибрати

---

Приклад 5 - Об'єднати CHOOSE та VLOOKUP функції для повернення значення в лівому стовпці

Як правило, ми використовуємо функцію VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) повернути значення на основі заданого значення з діапазону таблиці. Але з VLOOKUP функція, вона поверне значення помилки, тоді як стовпець повернення знаходиться ліворуч від стовпця пошуку, як показано на знімку екрана нижче:

У цьому випадку ви можете поєднати CHOOSE функція з функцією VLOOKUP для вирішення проблеми.

формула:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

Поясніть:

CHOOSE({1,2},B1:B7,A1:A7): як аргумент table_range у функції VLOOKUP. {1,2} означає відображати 1 або 2 як аргумент index_num на основі аргументу col_num у функції VLOOKUP. Тут col_num у функції VLOOKUP дорівнює 2, тому CHOOSE відображення функції як CHOOSE(2, B1:B7,A1:A7), означає вибрати значення з A1: A7.

---

Приклад 6 - Повернути день тижня або місяць на основі заданої дати

З CHOOSE функція, ви також можете повернути відносний день тижня та місяць на основі заданої дати.

Формула 1: повернути будній день за датою

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

Поясніть:

WEEKDAY(): аргумент index_num, щоб отримати номер дня тижня даної дати, наприклад, WEEKDAY (A5) повертає 6, тоді аргумент index_num дорівнює 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": аргументи списку значень, починайте з “неділі”, оскільки номер тижня “1” вказує на “неділю”.

Формула 2: повернути місяць за датою

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Поясніть:

MONTH(): аргумент index_num, який отримує номер місяця з даної дати, наприклад, MONTH (A5) повертає 3.

---

Приклад 7 - Повернення до дати наступного робочого дня / вихідних за даними сьогодні

У щоденній роботі ви можете розрахувати наступний робочий день або вихідні, виходячи із сьогоднішнього дня. Ось CHOOSE функція також може зробити вам послугу.

Наприклад, сьогодні 12, четвер, тепер потрібно отримати наступний робочий день та вихідні.

Формула 1: отримати дату сьогодні

=TODAY()

Результат: 12

Формула 2: отримати число днів тижня сьогодні

=WEEKDAY(TODAY())

Результат: 5 (тоді як сьогодні 12)

Список номерів робочого дня, як показано на знімку екрана:

Формула 3: отримати наступний робочий день

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Поясніть:

Today(): повернути поточну дату

WEEKDAY(TODAY()): аргумент_індексу в CHOOSE функція, отримайте номер робочого дня сьогодні, наприклад, неділя 1, понеділок 2 ...

1,1,1,1,1,3,2: аргумент списку значень у CHOOSE функція. Наприклад, якщо день тижня (сьогодні ()) повертає 1 (неділя), він вибирає 1 зі списку значень, то вся формула змінюється на = Сьогодні () + 1, що означає додати 1 день для повернення наступного понеділка. Якщо день тижня (сьогодні ()) повертає 6 (п’ятниця), він вибирає 3 зі списку значень, оскільки п’ятниця - це 3 дні далеко від наступного понеділка.

Результат (поки сьогодні 12):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12 + 20

= 12/21/2018

Формула 4: отримати наступний день вихідних

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

Поясніть:

6,5,4,3,2,1,1: аргумент списку значень у CHOOSE функція. Наприклад, якщо день тижня (сьогодні ()) повертає 1 (неділя), він вибирає 6 зі списку значень, то вся формула змінюється на = Сьогодні () + 6, що означає додавання 6 днів і повернення наступної суботи.

Результат:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12 + 20

= 12/22/2018

---

Зразок файлу