Note: The other languages of the website are Google-translated. Back to English
Увійти  \/ 
x
or
x
Реєстрація  \/ 
x

or

перевершувати IF функція

Функція IF - одна з найпростіших і найкорисніших функцій у книзі Excel. Він виконує простий логічний тест, який залежно від результату порівняння, і повертає одне значення, якщо результат ІСТИНА, або інше значення, якщо результат ФАЛЬШЕ.


 Синтаксис:

Синтаксис функції IF у програмі Excel:

=IF (logical_test, [value_if_true], [value_if_false])

doc, якщо функція 2


 аргументи:

  • logical_test: Вимагається. Це умова, яку ви хочете перевірити.
  • value_if_true: Необов’язково. Конкретне значення, яке потрібно повернути, якщо результат логічного_тесту має значення TRUE.
  • value_if_false: Необов’язково. Значення, яке потрібно повернути, якщо результат логічного_тесту - FALSE.

примітки:

1 Якщо значення_якщо_правда опускається:

  • Якщо значення_якщо_правда аргумент опущений у функції IF, наприклад, лише кома, що слідує за логічним_тестом, він поверне нуль, коли умова виконана. Наприклад: =IF(C2>100,, "Low ").
  • Якщо ви хочете використовувати порожню комірку замість нуля, якщо умова виконана, вам слід ввести подвійні лапки "" у другий параметр, наприклад: =IF(C2>100, "", "Low").
doc, якщо функція 3 doc, якщо функція 4

2 Якщо value_if_false опускається:

  • Якщо value_if_false параметр опущений у функції IF, він поверне FALSE, коли вказана умова не виконується. Як от: =IF(C2>100, "High").
  • Якщо після аргументу value_if_true поставити кому, він поверне нуль, коли вказана умова не буде виконана. Як от: =IF(C2>100, "High" ,).
  • Якщо ви введете подвійні лапки в "" третій параметр, порожня комірка повернеться, якщо умова не виконана. Як от: =IF(C2>100, "High" , "").
doc, якщо функція 5 doc, якщо функція 6 doc, якщо функція 7

 повернення:

Тест на конкретну умову повертає відповідне значення, яке ви надаєте для TRUE або FALSE.


 Приклади:

Приклад 1: Використання простої функції IF для чисел

Наприклад, припустимо, ви хочете перевірити список значень, якщо значення більше конкретного значення 100, відображається текст "Добре", якщо ні, повертається текст "Погано".

Введіть формулу нижче, і ви отримаєте результат нижче, як вам потрібно.

=IF(B2>100,"Good","Bad")

doc, якщо функція 8


Приклад 2: Використання функції IF для текстових значень

Випадок 1: Функція IF для текстових значень, що не враховують регістр:

Тут у мене є таблиця зі списком завдань та статусу завершення, тепер я хочу знати, які завдання потрібно виконувати, а які - ні. Коли текст у стовпці C буде заповнений, на дисплеї відображатиметься "Ні", інакше "Так" буде повернуто.

Будь ласка, застосуйте наступну формулу, тепер клітинка поверне «Ні», коли текст у стовпці С відображається як «заповнений», незалежно від того, чи це великі чи малі літери; якщо інший текст у колонці C буде повернуто "Так". Дивіться знімок екрана:

=IF(C2="completed", "No", "Yes")

doc, якщо функція 9

Випадок 2: Функція IF для текстових значень з урахуванням регістру:

Щоб протестувати текстові значення з урахуванням регістру, вам слід поєднати функцію IF з функцією EXACT, будь ласка, застосуйте формулу нижче, тоді буде розпізнаний лише текст із точною відповідністю, і ви отримаєте нижченаведений результат, як хочете:

=IF(EXACT(C2,"COMPLETED"), "No", "Yes")

doc, якщо функція 10

Випадок 3: Функція IF для текстових значень з частковим збігом:

Іноді вам потрібно перевірити значення комірок на основі часткового тексту, в цьому випадку вам слід використовувати функції IF, ISNUMBER та SEARCH разом.

Наприклад, якщо ви хочете перевірити клітинки, які містять текст «комп», а потім повернути відповідні значення, застосуйте формулу нижче. І ви отримаєте результат, як показано нижче:

=IF(ISNUMBER(SEARCH("comp",C2)), "No", "Yes")

doc, якщо функція 11

Примітки:

  • 1. Функція ПОШУК застосовується до тексту з чутливістю до регістру; якщо ви хочете перевірити текст з урахуванням регістру, вам слід замінити функцію ПОШУК на функцію ЗНАЙТИ. Подобається це:=IF(ISNUMBER(FIND("comp",C2)), "No", "Yes")
  • 2. Текстові значення як параметри у формулах IF, ви повинні укласти їх у "подвійні лапки".

Приклад 3: Використання функції IF для значень дати

Випадок 1: Функція IF для дат для порівняння дат із конкретною датою:

Якщо ви хочете порівняти дати, щоб перевірити, чи є вони більшими чи меншими за певну дату, функція IF також може зробити вам послугу. Оскільки функція IF не може розпізнати формат дати, вам слід поєднати з нею функцію DATEVALUE.

Будь ласка, застосуйте цю формулу, коли дата перевищує 4, буде повернуто "Так", інакше формула поверне текст "Ні", див. Знімок екрана:

=IF(D4>DATEVALUE("4/15/2019"), "Yes", "No")

doc, якщо функція 12

примітки: У наведеній вище формулі ви можете використовувати посилання на клітинку безпосередньо, не використовуючи також функцію DATEVALUE. Подобається це: =IF(D4>$D$1, "Yes", "No").

doc, якщо функція 13

Випадок 2: якщо функція перевірки дат для дат перевищує або менше 30 днів:

Якщо ви хочете визначити дати, які перевищують або менше 30 днів з поточної дати, ви можете поєднати функцію TODAY із функцією IF.

Введіть цю формулу:

Визначте дату старшу за 30 днів: =IF(TODAY()-C4>30,"Older date","")

Визначте дату, що перевищує 30 днів: =IF(C4-TODAY()>30, "Future date", "")

doc, якщо функція 14 doc, якщо функція 15

Примітка: Якщо ви хочете помістити обидва результати в один стовпець, вам потрібно використовувати вкладену функцію IF, як це:

=IF(C4-TODAY()>30, "Future date", IF(TODAY()-C4>30, "Older date", ""))

doc, якщо функція 16


Приклад 4: Використання функції IF із AND, OR функцією разом

Для нас є звичним поєднанням функцій IF, AND, OR в Excel.

Випадок 1: Використання функції IF з функціями AND, щоб перевірити, чи всі умови є істинними:

Я хочу перевірити, чи виконуються всі встановлені мною умови, наприклад: B4 - червоний, C4 - маленький, а D4> 200. Якщо всі умови ТУРЕ, позначте результат як “Так”; Якщо будь-яка умова неправдива, поверніть "Ні".

Застосуйте цю формулу, і ви отримаєте результат, як показано на наступному знімку екрана:

=IF(AND(B4="Red",C4="Small", D4>200),"Yes","No")

doc, якщо функція 17

Випадок 2: Використання функції IF з функціями АБО для перевірки будь-якої з умов відповідає дійсності:

Ви також можете використовувати функції IF та OR, щоб перевірити, чи відповідає будь-яка з умов, наприклад, я хочу визначити, чи містить клітинка в стовпці B текст "Синій" або "Червоний", якщо є будь-який текст у стовпці B, Відображається Так, інакше Ні повертається

Тут слід застосувати цю формулу, і буде показано наступний результат:

=IF(OR(B4="Red",B4="Blue"),"Yes","No")

doc, якщо функція 18

Випадок 3: Використання функції IF із функціями AND та OR разом:

У цьому прикладі я поєднаю функцію IF з обома функціями AND & OR одночасно. Припустимо, вам слід перевірити такі умови:

  • Condition 1: Column B = “Red” and Column D > 300;
  • Condition 2: Column B = “Blue” and Column D > 300.

Якщо виконується будь-яка з наведених умов, збіг повертається, інакше - Ні

Будь ласка, використовуйте цю формулу, і ви отримаєте такий результат, як вам потрібно:

=IF(AND(OR(B4="Red",B4= "Blue"), D4>300), "Match", "No")

doc, якщо функція 19


Приклад 5: Використання вкладеної функції IF

Функція IF використовується для перевірки умови та повернення одного значення, якщо умова виконана, і іншого значення, якщо воно не виконане. Але, іноді, вам потрібно перевірити більше однієї умови одночасно і повернути різні значення, ви можете використовувати вкладений IF, щоб вирішити цю роботу.

Оператор вкладеного IF, який поєднує в собі кілька умов IF, означає введення оператора IF всередині іншого оператора IF і повторення цього процесу кілька разів.

Синтаксис функції вкладеного IF в Excel такий:

=IF (condition1, result1, IF (condition2, result2, IF (condition3, result3,…)))

примітки: У програмі Excel 2007 та пізніших версіях ви можете вкласти до 64 функцій IF в одну формулу, а в Excel 2003 та попередніх версіях можна використовувати лише 7 вкладених функцій IF.

Випадок 1: Вкладена функція IF для перевірки кількох умов:

Класичне використання функції «Вкладений ІФ» полягає у присвоєнні кожному студенту оцінки на основі їх балів. Наприклад, у вас є таблиця зі студентами та їх результатами іспитів, тепер ви хочете класифікувати оцінки за таких умов:

doc, якщо функція 20

Будь ласка, застосуйте цю формулу, і ви отримаєте нижченаведений результат. Якщо оцінка більша або дорівнює 90, оцінка "Відмінно", якщо оцінка більша або дорівнює 80, оцінка "Добре", якщо оцінка більше або дорівнює 60, оцінка “Середня”, інакше оцінка “Погана”.

=IF(C2>=90, "Excellent", IF(C2>=80, "Good", IF(C2>=60, "Medium", "Poor")))

doc, якщо функція 21

Пояснення наведеної формули:

doc, якщо функція 22
  • IF(check if C2>=90, if true - returns "Excellent", or else
  • IF(check if C2>=80, if true - returns "Good", or else
  • IF(check if C2>=60, if true - returns "Medium", if false - returns "Poor")))

Випадок 2: Вкладена функція IF для розрахунку ціни на основі кількості:

Функцію Вкладеного IF також можна використовувати для розрахунку ціни товару на основі кількості.

Наприклад, ви хочете надати клієнтам знижку ціни залежно від кількості, більшої кількості, яку вони купують, більшої знижки вони отримають, як показано на знімку екрана нижче.

doc, якщо функція 23

Оскільки загальна ціна дорівнює кількості, помножте ціну, тому вам слід помножити зазначену кількість на значення, повернене вкладеними значеннями if. Будь ласка, використовуйте цю формулу:

=D2*IF(D2>=101,16, IF(D2>=50, 21, IF(D2>=25, 26, IF( D2>=11, 30, IF(D2>=1, 39, "")))))

doc, якщо функція 24

примітки: Ви також можете використовувати посилання на клітинки для заміни статичних номерів цін, коли при зміні вихідних даних вам не потрібно буде оновлювати формулу, використовуйте цю формулу: =D2*IF(D2>=101, B6, IF(D2>=50, B5, IF(D2>=25, B4, IF( D2>=11, B3, IF(D2>=1, B2, "")))))

doc, якщо функція 25

чайові: Використовуючи функцію IF для побудови тесту, ви можете використовувати такі логічні оператори:

Оператор Сенс Приклад опис
> Більш чим =IF(A1>10, "OK",) Якщо число в комірці А1 більше 10, формула повертає "ОК"; в іншому випадку повертається 0.
< Менш =IF(A1<10, "OK", "") Якщо число в комірці А1 менше 10, формула повертає "ОК"; інакше повертається порожня комірка.
>= Більше або дорівнює =IF(A1>=10, "OK", "Bad") Якщо число в комірці А1 більше або дорівнює 10, воно поверне "ОК"; в іншому випадку відображається "Погано".
<= Менше або дорівнює =IF(A1<=10, "OK", "No") Якщо число в комірці А1 менше або дорівнює 10, воно повертає "ОК"; в іншому випадку повертається "Ні".
= Дорівнює =IF(A1=10, "OK", "No") Якщо число в комірці А1 дорівнює 10, воно повертає "ОК"; в іншому випадку відображається "Ні".
<> Не дорівнює =IF(A1<>10, "No", "OK") Якщо число в комірці А1 не дорівнює 10, формула повертає "Ні"; інакше - "ОК".

Найкращі інструменти для підвищення продуктивності офісу

Kutools для Excel - допомагає виділитися з натовпу

Ви хотіли б швидко і довершити свою щоденну роботу? Kutools для Excel пропонує 300 потужних вдосконалених функцій (Об’єднайте робочі книги, підсумовуйте за кольором, розділіть вміст комірок, конвертуйте дату тощо) і заощаджуйте для вас 80% часу.

  • Розроблений для 1500 сценаріїв роботи, допомагає вирішити 80% проблем Excel.
  • Щодня зменшуйте тисячі клацань клавіатури та миші, знімайте втомлені очі та руки.
  • Станьте експертом Excel за 3 хвилини. Більше не потрібно згадувати будь-які болісні формули та коди VBA.
  • Безкоштовна 30-денна безкоштовна пробна версія. 60-денна гарантія повернення грошей. Безкоштовне оновлення та підтримка протягом 2 років.
Стрічка Excel (із встановленим Kutools для Excel)

Вкладка Office - Увімкнути читання та редагування з вкладками в Microsoft Office (включаючи Excel)

  • Одна секунда для перемикання між десятками відкритих документів!
  • Щодня зменшуйте сотні клацань мишею, прощайте руку миші.
  • Збільшує вашу продуктивність на 50% під час перегляду та редагування декількох документів.
  • Приносить ефективні вкладки в Office (включаючи Excel), як і Chrome, Firefox та New Internet Explorer.
Знімок екрана Excel (із встановленою вкладкою Office)
Say something here...
symbols left.
You are guest
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.