Як запустити кілька макросів із меню правої кнопки миші в Excel?

Якщо у вашій книзі є кілька макросів vba, вам слід відкрити вікно VBA, а потім вибрати макрос, коли потрібно запустити код. У цій статті я хотів би поговорити про те, як запускати макроси з меню правої кнопки миші, щоб зробити вашу роботу більш ефективною, як показано на лівому скріншоті.

Запустіть кілька макросів із меню правої клавіші з кодами VBA

Запустіть кілька макросів із меню правої клавіші з кодами VBA

Щоб запустити коди макросів у книзі за допомогою меню, що клацне правою кнопкою миші, вам можуть допомогти наступні кроки, виконайте наступні дії:

1. Отвір у Alt + F11 ключі, щоб відкрити Microsoft Visual Basic для додатків вікна.

2. Потім двічі клацніть ThisWorkbook в лівій Проекти , а потім скопіюйте та вставте наведений нижче код VBA у порожній модуль.

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3. Досі в Microsoft Visual Basic для додатків вікно, натисніть Insert > Модуліта вставте наступний код у цей модуль.

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4. Після вставки кодів натисніть Tools > посилання, А в Посилання-VBAProject відобразиться діалогове вікно, а потім перевірте Microsoft Visual Basic для розширення програм 5.3 опція в Доступні посилання вікно списку, див. знімок екрана:

5. Потім натисніть OK щоб вийти з діалогового вікна, вам слід зберегти цю книгу як Книга Excel з підтримкою макросів формат, див. знімок екрана:

6. Нарешті, перезапустіть книгу, щоб почали діяти коди, і тепер, коли ви клацаєте правою кнопкою миші клітинку, a Запустіть макрос параметр вставляється в меню правої клавіші миші, і всі макроси у вашій книзі перелічені в підменю як наступний знімок екрана:

7. Тоді ви можете запустити код, просто натиснувши його.