Note: The other languages of the website are Google-translated. Back to English

Видаліть або видаліть числові символи з текстових рядків

Якщо ви хочете видалити всі числа лише зі списку текстових рядків, але зберегти інші нецифрові символи, можливо, в Excel є деякі формули, які можуть вам зробити послугу.


Видаліть або видаліть усі числа з текстових рядків у Excel

Щоб видалити лише числа з буквено-цифрових рядків, вам може допомогти складна формула масиву, яка поєднує функції TEXTJOIN, MID, ROW, IF, ISERR, LEN та INDIRECT. (примітки: Ця формула добре працює лише в Excel 2019 та Office 365.) Загальний синтаксис:

=TEXTJOIN("",TRUE,IF(ISERR(MID(text,ROW(INDIRECT("1:"&LEN(text))),1)+0),MID(text,ROW(INDIRECT("1:"&LEN(text))),1),""))
  • text: текстовий рядок або значення комірки, з якого потрібно видалити всі числа.

1. Скопіюйте або введіть наведену нижче формулу в порожню клітинку, де ви хочете вивести результат:

=TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),""))

2. Потім натисніть Ctrl + Shift + Enter клавіші одночасно, щоб отримати перший результат, див. знімок екрана:

3. А потім, виділіть комірку формули, перетягніть маркер заповнення до комірок, які ви хочете використовувати, усі числа були вилучені з текстових рядків, див. Знімок екрана:


Пояснення формули:

РЯДОК (НЕПРАВИЙ ("1:" & LEN (A2))): Функція INDIRECT у функції ROW поверне список масивів, довжина якого є довжиною комірки A2, як показано нижче, і ця частина розпізнається як start_num у функції MID.
{1;2;3;4;5;6;7;8;9;10;11;12;13;14;15;16;17;18;19;20;21}

MID (A2, ROW (INDIRECT ("1:" & LEN (A2))), 1): Ця функція MID використовується для вилучення тексту з комірки A2, щоб отримати один символ, і вона поверне такий масив:
{"5"; "0"; "0"; ""; "K"; "u"; "t"; "o"; "o"; "l"; "s"; ""; "f" ; "o"; "r"; ""; "E"; "x"; "c"; "e"; "l"}

MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0: Додавання значення 0 після цього масиву використовується для перетворення тексту на число, числове текстове значення буде перетворено на число, а нечислові значення відображатимуться як значення помилки #VALUE, наприклад:
{"5"; "0"; "0"; # ЗНАЧЕННЯ!; # ЗНАЧЕННЯ!; # ЗНАЧЕННЯ!; # ЗНАЧЕННЯ!; # ЗНАЧЕННЯ!; # ЗНАЧЕННЯ! !; # ЦІННІСТЬ! !; # ЦІННІСТЬ! ...}

IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),""): Функція IF використовується, щоб перевірити, чи є масив, що повертається функцією MID, значенням помилки чи ні. Якщо це значення помилки, отримайте нечисловий символ, використовуючи другу функцію MID, інакше порожні рядки відображаються так:
{""; ""; ""; ""; "K"; "u"; "t"; "o"; "o"; "l"; "s"; ""; "f"; "o ";" r ";" ";" E ";" x ";" c ";" e ";" l "}

TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),"")): Нарешті, функція TEXTJOIN об’єднає всі значення і проігнорує порожній рядок, щоб отримати результат.


Примітки:

1. Під час видалення числових символів, можливо, залишилося кілька зайвих пробілів, щоб видалити всі зайві пробіли, слід обернути формулу у функцію TRIM, як показано нижче:

=TRIM(TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),"")))

2. Щоб видалити числа з текстових рядків у ранніх версіях Excel, застосуйте таку формулу:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,1,""),2,""),3,""),4,""),5,""),6,""),7,""),8,""),9,""),0,"")


Використовувані відносні функції:

  • TEXTJOIN:
  • Функція TEXTJOIN об'єднує кілька значень з рядка, стовпця або діапазону комірок із певним роздільником.
  • MID:
  • Функція MID використовується для пошуку та повернення певної кількості символів із середини даного текстового рядка.
  • ROW:
  • Функція Excel ROW повертає номер рядка посилання.
  • INDIRECT:
  • Функція Excel INDIRECT перетворює текстовий рядок у дійсне посилання.
  • LEN:
  • Функція LEN повертає кількість символів у текстовому рядку.
  • IF:
  • Функція IF виконує простий логічний тест, який залежно від результату порівняння повертає одне значення, якщо результат ІСТИНА, або інше значення, якщо результат - FALSE.
  • ISERR:
  • Функція ISERR використовується для повернення TRUE для будь-якого типу помилки, крім помилки # N / A.

Більше статей:


Найкращі інструменти для підвищення продуктивності офісу

Kutools для Excel - допомагає виділитися з натовпу

Бажаєте виконувати щоденну роботу швидко та якісно? Kutools для Excel надає 300 потужних розширених функцій (об’єднання робочих книг, підсумовування за кольором, розділення вмісту клітинок, перетворення дати тощо) і заощаджує 80% вашого часу.

  • Розроблений для 1500 сценаріїв роботи, допомагає вирішити 80% проблем Excel.
  • Щодня зменшуйте тисячі клацань клавіатури та миші, знімайте втомлені очі та руки.
  • Станьте експертом Excel за 3 хвилини. Більше не потрібно згадувати будь-які болісні формули та коди VBA.
  • Безкоштовна 30-денна безкоштовна пробна версія. 60-денна гарантія повернення грошей. Безкоштовне оновлення та підтримка протягом 2 років.
Стрічка Excel (із встановленим Kutools для Excel)

Вкладка Office - Увімкнути читання та редагування з вкладками в Microsoft Office (включаючи Excel)

  • Одна секунда для перемикання між десятками відкритих документів!
  • Щодня зменшуйте сотні клацань мишею, прощайте руку миші.
  • Збільшує вашу продуктивність на 50% під час перегляду та редагування декількох документів.
  • Приносить ефективні вкладки в Office (включаючи Excel), як і Chrome, Firefox та New Internet Explorer.
Знімок екрана Excel (із встановленою вкладкою Office)
Коментарі (0)
Поки немає оцінок. Оцініть першим!
There are no comments posted here yet
Залишайте свої коментарі
Публікація як гість
×
Оцініть цю публікацію:
0   Персонажі
Рекомендовані місця

Слідуй за нами

Copyright © 2009 - WWW.extendoffice.com. | Всі права захищені. На основі ExtendOffice. | Карта сайту
Microsoft та логотип Office є товарними знаками або зареєстрованими товарними знаками Microsoft Corporation у США та / або інших країнах.
Захищений Sectigo SSL