Як очистити всі категорії з Outlook?

Припустимо, у вашій програмі Outlook до категорії кольорів застосовано багато елементів. Якщо вам потрібно очистити всі ці категорії з елементів, як би ви могли швидко та легко впоратися з цією роботою в Outlook?

Видаліть усі категорії з певної папки за допомогою функції Очистити всі категорії

Видаліть усі категорії з певного облікового запису за допомогою коду VBA

Видаліть усі категорії з певної папки за допомогою функції Очистити всі категорії

Якщо вам просто потрібно очистити категорії в певній папці, зробіть так:

1. Клацніть папку, з якої потрібно видалити кольорові категорії, а потім натисніть Ctrl + A щоб вибрати всі елементи.

2. Потім клацніть правою кнопкою миші, а потім виберіть Узагальнити > Очистити всі категорії у контекстному меню див. знімок екрана:

doc clear категорія 1

3. А потім усі категорії кольорів у цій конкретній папці були очищені відразу.

Видаліть усі категорії з певного облікового запису за допомогою коду VBA

Щоб очистити всі категорії з усіх елементів, таких як електронні листи, завдання, контакти, нотатки тощо, з облікового запису, наведений нижче код VBA може зробити вам послугу:

1. Клацніть на електронну адресу облікового запису, з якої потрібно очистити всі категорії, і натисніть і утримуйте ALT + F11 ключі, щоб відкрити Microsoft Visual Basic для додатків вікна.

2. Клацання Insert > Модуліта вставте наступний макрос у Модулі Вікно

Код VBA: Очистити всі категорії з певного облікового запису:

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3. Потім натисніть F5 клавішу, щоб запустити його, а потім з'явиться підказка, щоб нагадати вам, що всі категорії з вибраного облікового запису були очищені, див. знімок екрана:

doc clear категорія 2