Як зберегти категорію під час відповіді або пересилання електронної пошти в Outlook? 

Зазвичай, коли ви відповідаєте або пересилаєте електронний лист, який я класифікував, категорія буде автоматично видалена з надісланого електронного листа. Якщо ви хочете зберегти категорію вихідних електронних листів у відповідях або пересиланні, у цій статті буде представлено метод боротьби з нею.

Зберігайте категорію, відповідаючи або пересилаючи електронний лист із кодом VBA

---

Зберігайте категорію, відповідаючи або пересилаючи електронний лист із кодом VBA

1. Утримуйте клавішу ALT + F11 ключі, щоб відкрити Microsoft Visual Basic для додатків вікна.

2, в Microsoft Visual Basic для додатків вікно, двічі клацніть ThisOutlookSession від Проект1 (VbaProject.OTM) , щоб відкрити режим, а потім скопіюйте та вставте наступний код у порожній модуль.

Код VBA: Зберігайте категорію під час відповіді або пересилання електронного листа:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Потім збережіть і закрийте це вікно коду, закрийте та перезапустіть Outlook, тепер, коли ви відповідаєте або пересилаєте електронне повідомлення з категорією, категорія зберігатиметься у вихідному повідомленні в Відправлені, див. скріншот: