Як надрукувати завдання на основі категорії в Outlook?

Припустимо, у ваших завданнях Outlook є різні кольорові категорії, і тепер ви хочете надрукувати списки завдань на основі категорій на різних сторінках. Як ви могли вирішити цю роботу в Outlook?

Друкувати завдання на основі категорій на різних сторінках вручну по одному

Друкувати завдання на основі категорій на різних сторінках із кодом VBA

Друкувати завдання на основі категорій на різних сторінках вручну по одному

У програмі Outlook ви можете вручну друкувати завдання на основі різних категорій на різних сторінках по одному, виконайте наступне:

1. Запустіть Outlook, перейдіть на панель завдань і виберіть папку завдань, яку потрібно надрукувати, а потім натисніть Ctrl + E щоб активувати Пошук , а потім під Пошук вкладка, клацніть Категорії і виберіть одну кольорову категорію, яку потрібно роздрукувати, див. знімок екрана:

завдання друку документації за категорією 1

2. А потім усі завдання з певною категорією кольорів перераховані відразу, див. Знімок екрана:

завдання друку документації за категорією 2

3. Потім натисніть на кнопку філе > друк щоб роздрукувати цей список завдань, як показано на наступному знімку екрана:

завдання друку документації за категорією 3

4. Повторіть наведені вище кроки, щоб вручну роздрукувати списки завдань з іншими кольоровими категоріями.

Друкувати завдання на основі категорій на різних сторінках із кодом VBA

Ось код VBA, який може допомогти вам роздрукувати завдання на основі категорії одночасно на різних сторінках. Будь ласка, виконайте такі дії:

1. Іди до Завдання панелі та виберіть папку завдань, яку потрібно надрукувати.

2. Потім утримуйте клавішу ALT + F11 ключі, щоб відкрити Microsoft Visual Basic для додатків вікна.

3. А потім натисніть Insert > Модулі, скопіюйте та вставте код нижче у відкритий порожній модуль:

Код VBA: Друк завдань на основі категорій на різних сторінках:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Потім натисніть Tools > посилання в Microsoft Visual Basic для додатків вікно, у спливаючому Список літератури-Проект1 діалогове вікно, поставте галочку Бібліотека об’єктів Microsoft Excel та Виконання сценаріїв Microsoft варіанти з Доступні посилання вікно списку, див. знімок екрана:

завдання друку документації за категорією 4

5. А потім натисніть OK зараз натисніть кнопку F5 клавішу для запуску цього коду, після закінчення коду списки завдань з різними категоріями будуть надруковані на різних сторінках.